**Лабораторная работа 6**

**Сценарии WSH для доступа к файловой системе. Объектная модель FileSystemObject**

**Получение сведений о диске**

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Имя: DriveInfo.vbs

' Язык: VBScript

' Описание: Вывод на экран свойств диска C

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

'Объявляем переменные

Dim FSO,D,TotalSize,FreeSpace,s

'Создаем объект FileSystemObject

Set FSO = WScript.CreateObject("Scripting.FileSystemObject")

'Создаем объект Drive для диска C

Set D = FSO.GetDrive("C:")

s = "Информация о диске C:" & VbCrLf

'Получаем серийный номер диска

s = s &"Серийный номер: " & D.SerialNumber & VbCrLf

'Получаем метку тома диска

s = s & "Метка тома: " & D.VolumeName & VbCrLf

'Вычисляем общий объем диска в килобайтах

TotalSize = D.TotalSize/1024

s = s & "Объем: " & TotalSize & " Kb" & VbCrLf

'Вычисляем объем свободного пространства диска в килобайтах

FreeSpace = D.FreeSpace/1024


s = s & "Свободно: " & FreeSpace & " Kb" & VbCrLf

'Выводим свойства диска на экран

WScript.Echo s

'\*\*\*\*\*\*\*\*\*\*\*\*\* Конец \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Листинг 6.1. Вывод информации о диске (VBScript)



**Получение сведений о каталоге**

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Имя: FolderInfo.vbs

' Язык: VBScript

' Описание: Вывод на экран даты создания текущего каталога

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Dim FSO,WshShell,FoldSize,s 'Объявляем переменные

'Создаем объект FileSystemObject

Set FSO = WScript.CreateObject("Scripting.FileSystemObject")

'Создаем объект WshShell

Set WshShell = WScript.CreateObject("WScript.Shell")

'Определяем каталог, из которого был запущен сценарий

'(текущий каталог)

Set Folder = FSO.GetFolder(WshShell.CurrentDirectory)

'Получаем имя текущего каталога

s = "Текущий каталог: " & Folder.Name & VbCrLf

'Получаем дату создания текущего каталога

s = s & "Дата создания: " & Folder.DateCreated & VbCrLf

'Вычисляем размер текущего каталога в килобайтах

FoldSize=Folder.Size/1024


s = s & "Объем: " & FoldSize & " Kb" & VbCrLf

'Выводим информацию на экран

WScript.Echo s

'\*\*\*\*\*\*\*\*\*\*\*\*\* Конец \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Листинг 6.2. Вывод информации о каталоге (VBScript)



**Проверка существования диска, каталога или файла**

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Имя: IsExistsFile.vbs

' Язык: VBScript

' Описание: Проверка существования файла

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Dim FSO,FileName 'Объявляем переменные

'Создаем объект FileSystemObject

Set FSO = WScript.CreateObject("Scripting.FileSystemObject")

FileName = "C:\boot.ini"

if FSO.FileExists(FileName) Then

'Выводим информацию на экран

WScript.Echo "Файл " & FileName & " существует"

else


'Выводим информацию на экран

WScript.Echo "Файл " & FileName & " не существует"

end if

'\*\*\*\*\*\*\*\*\*\*\*\*\* Конец \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Листинг 6.4. Проверка существования файла (VBScript)



**Получение списка всех имеющихся дисков**

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Имя: ListDrives.vbs

' Язык: VBScript

' Описание: Получение списка всех имеющихся дисков

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

'Объявляем переменные

Dim FSO,s,ss,Drives,D

'Создаем объект FileSystemObject

Set FSO = WScript.CreateObject("Scripting.FileSystemObject")

'Создаем коллекцию дисков, имеющихся в системе

Set Drives = FSO.Drives

s = ""

'Перебираем все диски в коллекции

For Each D In Drives

'Получаем букву диска

s = s & D.DriveLetter

s = s & " - "

if (D.DriveType = 3) then 'Проверяем, не является ли диск сетевым

'Получаем имя сетевого ресурса

ss = D.ShareName

else

'Диск является локальным

if (D.IsReady) then 'Проверяем готовность диска

'Если диск готов, то получаем метку тома для диска

ss = D.VolumeName

else

ss = "Устройство не готово"

end if

s = s & ss & VbCrLf

end if


Next

'Выводим полученные строки на экран

WScript.Echo s

'\*\*\*\*\*\*\*\*\*\*\*\*\* Конец \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Листинг 6.5. Построение списка всех имеющихся дисков (VBScript)



**Получение списка всех подкаталогов заданного каталога**

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Имя: ListSubFold.vbs

' Язык: VBScript

' Описание: Получение списка всех подкаталогов заданного каталога

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

'Объявляем переменные

Dim FSO,F,SFold,SubFolders,Folder,s

'Создаем объект FileSystemObject

Set FSO = WScript.CreateObject("Scripting.FileSystemObject")

'Путь к каталогу

SFold = "C:\Program Files"

s = "Каталог " & SFold & VbCrLf

s = s & "Подкаталоги:" & VbCrLf

'Создаем объект Folder для каталога C:\Program Files

Set F=FSO.GetFolder(SFold)

'Создаем коллекцию подкаталогов каталога C:\Program Files

Set SubFolders = F.SubFolders

'Цикл по всем подкаталогам

For Each Folder In SubFolders

'Добавляем строку с именем подкаталога

s = s & Folder & VbCrLf


Next

'Выводим полученные строки на экран

WScript.Echo s

'\*\*\*\*\*\*\*\*\*\*\*\*\* Конец \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/

Листинг 6.6. Построение списка подкаталогов (VBScript)



**Получение списка всех файлов заданного каталога**

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Имя: ListFiles.vbs

' Язык: VBScript

' Описание: Получение списка всех файлов заданного каталога

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

'Объявляем переменные

Dim FSO,F,File,Files,WshShell,PathList,s

'Создаем объект FileSystemObject

Set FSO = WScript.CreateObject("Scripting.FileSystemObject")

'Создаем объект WshShell

Set WshShell = WScript.CreateObject("WScript.Shell")

'Создаем объект WshSpecialFolders

Set WshFldrs = WshShell.SpecialFolders

'Определяем путь к папке Мои документы

PathList = WshFldrs.item("MyDocuments") & "\"

'Создаем объект Folder для папки Мои документы

Set F = FSO.GetFolder(PathList)

'Создаем коллекцию файлов каталога Мои документы

Set Files = F.Files

s = "Файлы из каталога " & PathList & VbCrLf

'Цикл по всем файлам

For Each File In Files

'Добавляем строку с именем файла

s = s & File.Name & VbCrLf


Next

'Выводим полученные строки на экран

WScript.Echo s

'\*\*\*\*\*\*\*\*\*\*\*\*\* Конец \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Листинг 6.7. Построение списка файлов в каталоге (JScript)



**Создание текстового файла**

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Имя: CreateTempFile.vbs

' Язык: VBScript

' Описание: Создание временного файла со случайным именем

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Dim FSO,FileName,F,s 'Объявляем переменные

'Создаем объект FileSystemObject

Set FSO = WScript.CreateObject("Scripting.FileSystemObject")

'Генерируем случайное имя файла

FileName = FSO.GetTempName

'Создаем файл с именем FileName

Set F = FSO.CreateTextFile(FileName, true)

'Закрываем файл


F.Close


'Сообщаем о создании файла

WScript.Echo "Был создан файл " & FileName

'\*\*\*\*\*\*\*\*\*\*\*\*\* Конец \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Листинг 6.9. Создание временного файла со случайным именем (VBScript)





**Операции чтения и записи строк для текстового файла**

|  |  |  |  |  |
| --- | --- | --- | --- | --- |
| Таблица 6.2. Параметр Iomode | | | | |
| **Константа** | **Значение** | | **Описание** | |
| ForReading | 1 | | Файл открывается только для чтения, записывать информацию в него нельзя | |
| ForWriting | 2 | | Файл открывается для записи. Если файл с таким именем уже существовал, то при новой записи его содержимое теряется | |
| ForAppending | 8 | | Файл открывается для добавления. Если файл уже существовал, то информация будет дописываться в конец этого файла | |
| Таблица 6.3. Параметр Format | | | | |
| **Константа** | | **Значение** | | **Описание** |
| TristateUseDefault | | -2 | | Файл открывается в формате, используемом системой по умолчанию |
| TristateTrue | | -1 | | Файл открывается в формате Unicode |
| TristateFalse | | 0 | | Файл открывается в формате ASCII |

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Имя: TextFile.vbs

' Язык: VBScript

' Описание: Запись строк в текстовый файл и чтение из него

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Dim FSO,F,TextStream,s 'Объявляем переменные

' Инициализируем константы

Const ForReading = 1, ForWriting = 2, TristateUseDefault = -2

' Создаем объект FileSystemObject

Set FSO=WScript.CreateObject("Scripting.FileSystemObject")

' Создаем в текущем каталоге файл test1.txt

FSO.CreateTextFile "test1.txt"

' Создаем объект File для файла test1.txt

set F=FSO.GetFile("test1.txt")

' Создаем объект TextStream (файл открывается для записи)

Set TextStream=F.OpenAsTextStream(ForWriting, TristateUseDefault)

' Записываем в файл строку

TextStream.WriteLine "Это первая строка"

' Закрываем файл

TextStream.Close

' Открываем файл для чтения

Set TextStream=F.OpenAsTextStream(ForReading, TristateUseDefault)

' Считываем строку из файла

s=TextStream.ReadLine

' Закрываем файл


TextStream.Close

' Отображаем строку на экране

WScript.Echo "Первая строка из файла test1.txt:" & vbCrLf & vbCrLf & s

'\*\*\*\*\*\*\*\*\*\*\*\*\* Конец \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Листинг 6.10. Запись информации в текстовый файл и чтение из него (VBScript)



**Копирование и перемещение файлов и каталогов**

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Имя: CopyFile.vbs

' Язык: VBScript

' Описание: Создание и копирование файла

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

'Объявляем переменные

Dim FSO,F,WshShell,WshFldrs,PathCopy

'Создаем объект FileSystemObject

Set FSO = WScript.CreateObject("Scripting.FileSystemObject")

'Создаем файл

Set F = FSO.CreateTextFile("C:\TestFile.txt", true)

'Записываем в файл строку

F.WriteLine "Тестовый файл"

'Закрываем файл

F.Close

'Создаем объект WshShell

Set WshShell = WScript.CreateObject("WScript.Shell")

'Создаем объект WshSpecialFolders

Set WshFldrs = WshShell.SpecialFolders

'Определяем путь к рабочему столу

PathCopy = WshFldrs.item("Desktop")+"\"

'Создаем объект File для файла C:\TestFile.txt


Set F = FSO.GetFile("C:\TestFile.txt")

'Копируем файл на рабочий стол

F.Copy PathCopy

'\*\*\*\*\*\*\*\*\*\*\*\*\* Конец \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Листинг 6.11. Создание текстового файла и копирование его в другой каталог (VBScript)



**Удаление файлов и каталогов**

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

' Имя: DeleteFile.vbs

' Язык: VBScript

' Описание: Создание и удаление файла

'\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

'Объявляем переменные

Dim FSO,F,FileName

'Создаем объект FileSystemObject

Set FSO = WScript.CreateObject("Scripting.FileSystemObject")

'Задаем имя файла

FileName="C:\TestFile.txt"

'Создаем файл

Set F = FSO.CreateTextFile(FileName, true)

'Записываем в файл строку

F.WriteLine "Тестовый файл"

'Закрываем файл

F.Close

WScript.Echo "Файл создан"

FSO.DeleteFile FileName

WScript.Echo "Файл удален"

'\*\*\*\*\*\*\*\*\*\*\*\*\* Конец \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

Листинг 6.12. Создание и удаление файла (VBScript)

